3.7 契約ネットプロトコル

複数のエージェントが協調動作するためには，何らかの協調プロトコルが必要となります．本節では，契約ネットプロトコル(Contract Net Protocol: CNP)と呼ばれる協調プロトコルを用いたエージェントについて説明します．
教科書p.90 "3.7 適切なエージェントを探して協調する" の内容に相当します．

概要

• 3つのホテルX，Y，Zがあります．
• ホテルの予約受付業務を行うエージェントHotel_X，Hotel_Y，Hotel_Zが動作しています．

ホテル	エージェント	宿泊料金	朝食の有無	駅から徒歩
X	Hotel_X	8,000円	あり	10分
Y	Hotel_Y	10,000円	あり	5分
Z	Hotel_Z	5,000円	なし	7分

• 旅行者userは宿泊するホテルを探しています．見知らぬ土地でホテルに関する情報がないため，代理店でホテルを探してもらおうとしています．
• 代理店のエージェントManagerは，userからの要望をもとに適切なホテルを探します．代理店が把握している各ホテルに対して問い合わせを行い，最も適切なホテルを探し出します．

メッセージの流れ

• 契約ネットプロトコルは，マネージャとコントラクタの間の協調プロトコルです．
  • マネージャとは，タスクを実行してくれるエージェントを探すエージェントです．タスクを実行するのに最適なエージェントが分からないので，可能性のあるエージェントに タスク通知(task-announcement) メッセージを送り，反応を待ちます．
  • コントラクタとは，タスクを受注しようとするエージェントです．マネージャから届いたタスクについて，自分が実行できるかどうかを判断します．実行できそうな場合，その条件を記した 入札(bid) メッセージをマネージャに返信します．
  • マネージャは，届いた入札メッセージから最適なものを選択し， 落札(award) メッセージを返信して，タスク実行の契約を結びます．
  • 落札を受信したコントラクタは，タスクを実行し，その結果を 結果報告(report) メッセージで報告します．
• 以上のように契約ネットプロトコルでは，タスク通知→入札→落札→結果報告の順でメッセージ通信を行います．が，本節で示すプログラムでは次のように変更してあります．
  • task-announcementではなく，request-bidというパフォーマティブでタスク通知を表します．
  • コントラクタは，受け取ったタスク通知を実行できない場合 giveup メッセージを返します．
  • 結果報告は行いません．

プログラム

Manager.groovy

public class Manager extends TAG {

    def loop(msg) {
        if (msg._p=='request-information' &&
            msg.charge!=null && msg.toho!=null && msg.breakfast!=null) {
            // 徒歩と朝食の条件を3つのエージェントに送信し，全ての返事を待つ
            def replies = request(['Hotel_X', 'Hotel_Y', 'Hotel_Z'],
                                  [_p:'request-bid', toho:msg.toho, breakfast:msg.breakfast])
            def bids = replies.findAll{it._p == 'bid'} // bidだけを集める
            if (msg.charge=='cheap') {
                def m = bids.min{it.charge} // 料金が最低なbidを選ぶ
                reply(m, [_p:'award', msg:m])
                reply(msg, [_p:'inform', msg:m])
            }
        } else {
            reply(msg, [_p:'sorry', msg:msg])
        }
    }
}

• 7行：Hotel_X, Hotel_Y, Hotel_Zにタスク通知を送信し，応答メッセージをrepliesに格納します．
• 9行：応答メッセージのうち bid メッセージのみをbidsに格納します．
• 10行：userは低料金のホテルを探している場合に，
• 11行：bidsの中から料金が最小の bid メッセージをmに格納し，
• 12行：award メッセージを送信し，
• 13行：userにはホテルの情報を返信します．

Hotel_X.groovy

class Hotel_X extends TAG {

    def info = [charge:8000, toho:10, breakfast:'yes'] // 料金8000円，徒歩10分, 朝食あり

    def loop(msg) {
        if (msg._p=='request-bid' && msg.toho!=null && msg.breakfast!=null) {
            if (msg.toho >= info.toho && msg.breakfast == info.breakfast) {
                reply(msg, [_p:'bid', charge:info.charge, toho:info.toho, breakfast:info.breakfast])
            } else {
                reply(msg, [_p:'giveup'])
            }
        } else if (msg._p=='award') {
            println("award:" + msg)
        } else {
            reply(msg, [_p:'sorry', msg:msg])
        }
    }
}

• 6行：タスク通知である request-bid を受信したときに，
• 7行：そのタスクが実行可能ならば(宿泊要求をみたせるならば)，
• 8行：入札を意味する bid メッセージを返信し，
• 10行：そうでなければ，giveup メッセージを返信します．
• 12行：落札を意味する award メッセージを受信したときは，
• 13行：そのメッセージを表示します．

Hotel_Y.groovy

class Hotel_Y extends Hotel_X {
    def setup() {
        info = [charge:10000, toho:5, breakfast:'yes'] // 料金10000円，徒歩5分, 朝食あり
    }
}

• info以外はHotel_Xと同じなので，Hotel_Xのサブクラスとして定義します．
• setup()でinfoの値を再設定しています．

Hotel_Z.groovy

class Hotel_Z extends Hotel_X {
    def setup() {
        info = [charge:5000, toho:7, breakfast:'no'] // 料金5000円，徒歩7分, 朝食なし
    }
}

• info以外はHotel_Xと同じなので，Hotel_Xのサブクラスとして定義します．
• setup()でinfoの値を再設定しています．

動作方法

• Managerに[_p:'request-information', charge:'cheap', toho:10, breakfast:'yes']を送信します．これは，次のホテルを探しているという意味です．
  • 料金が安い
  • 駅から徒歩10分以内
  • 朝食付き
• Managerは[_p:'request-bid', toho:msg.toho, breakfast:msg.breakfast]をタスク通知として3つのホテルエージェントに送信します．
• 受信した request-bid に対し，3つのホテルエージェントは次のメッセージをManagerに返信します．

エージェント	メッセージ	意味
Hotel_X	[_p:'bid', charge:8000, toho:10, breakfast:'yes']	料金8,000円，徒歩10分，朝食付き
Hotel_Y	[_p:'bid', charge:10000, toho:5, breakfast:'yes']	料金10,000円，徒歩5分，朝食付き
Hotel_Z	[_p:'giveup']	条件を満たすことができません

• Managerは受信した bid のうち，料金の安いHotel_Xを選び，award を送ります．

課題

1. Hotel_Zがaward を受け取るには，userはManagerにどのようなメッセージを送ればいいのかを考えてみましょう．
2. userがManagerに[_p:'request-information', charge:'cheap', toho:10, breakfast:'yes']を送信したときにaward を受け取れるHotel_Wを作成してみましょう．

エージェントプログラムの新規登録

• 配布したシステムには，今回のプログラムが含まれていません．
• 新規にプログラムを登録するには，次のいずれかの方法で行います．
  • Web-UIから作成する方法：
    1. show files にチェックを入れます．
    2. New をクリックします．
    3. Manager.groovyなどのファイル名を入力します．
    4. エージェントプログラムがagentフォルダに作成され，また新規のエージェントが起動します．
    5. エディタで内容を書き換えた後，save&restart をクリックします．変更が反映されます．
  • ファイルを作成する方法：
    1. tagserver.jarと同じフォルダにあるagentフォルダ内に新規ファイルを作成し保存します．文字コードはUTF-8(BOMなし)での文字コードで保存します．Windowsのメモ帳はファイル先頭にBOMが付くので使えません．
    2. 保存後にエージェントが自動的に起動します．